geo1007-labinstructions

GEO1007 Lab 8 - Semantic Web and Linked Data

A. RCE linked data

Go to https://yasgui.triply.cc/, a query interface for SPARQL queries.
Execute the following query (which, next to defining a query also defines the data):

prefix geo: <http://www.opengis.net/ont/geosparql#>
select ?pointLabel where {
  values (?pointLabel) {
    (
    "Point Nemo is the place in the ocean that is farthest from land"
    )
  }
}

See what comes back as response (look under: Table and Response).

Now perform the next query:

prefix geo: <http://www.opengis.net/ont/geosparql#>
select * where {
  values (?point ?pointTooltip ?pointLabel ?pointColor) {
    ("Point (-123.393333 -48.876667)"^^geo:wktLiteral
    "Point Nemo"
    "Point Nemo is the place in the ocean that is farthest from land"
    "blue")
  }
}

❓ Question / Result #1.a
Summarize what is visible under the Geo tab and add in your report a description and screenshot of this.

Now we will work with a different query (originating from: https://linkeddata.cultureelerfgoed.nl/rce/-/queries/rijksmonumenten-gemeente-provincie/9).
First, add into the input box at the top of the page (next to the wheel icon) the following SPARQL end point: https://api.linkeddata.cultureelerfgoed.nl/datasets/rce/cho/services/cho/sparql (do not forget to press Enter).
Second, perform the query:

prefix graph: <https://linkeddata.cultureelerfgoed.nl/graph/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix ceo: <https://linkeddata.cultureelerfgoed.nl/def/ceo#>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix rn: <https://data.cultureelerfgoed.nl/term/id/rn/>
prefix owms: <https://linkeddata.cultureelerfgoed.nl/graph/owms>

select DISTINCT 
  (iri(concat("https://monumentenregister.cultureelerfgoed.nl/monumenten/", ?rijksmonumentnummer)) as ?monumentenregister)
  ?rijksmonumentnummer ?straat ?huisnummer ?adres ?provincie ?gemeente ?postcode ?woonplaatsnaam ?functie ?datumInschrijving

where {
  graph graph:instanties-rce {
    ?rijksmonument 
      ceo:rijksmonumentnummer ?rijksmonumentnummer;
      ceo:datumInschrijvingInMonumentenregister ?datumInschrijving;
      ceo:heeftJuridischeStatus rn:b2d9a59a-fe1e-4552-9a05-3c2acddff864;
      ceo:heeftMonumentAard rn:fc966a68-8863-4970-a83e-110f96006c21;
      ceo:heeftBasisregistratieRelatie ?basisrel.

    ?basisrel ceo:heeftProvincie ?prov;
              ceo:heeftGemeente ?gem.

    OPTIONAL { 
      ?basisrel ceo:heeftBAGRelatie ?bagrelatie.

      OPTIONAL { ?bagrelatie ceo:volledigAdres ?adres. }
      OPTIONAL { ?bagrelatie ceo:postcode ?postcode_. }
      OPTIONAL { ?bagrelatie ceo:woonplaatsnaam ?woonplaatsnaam. }
      OPTIONAL { ?bagrelatie ceo:openbareRuimte ?straat. }
      OPTIONAL { ?bagrelatie ceo:huisnummer ?huisnummer. }
    }

    BIND(replace(str(?postcode_), "([0-9]{4})([A-Z]{2})", "$1 $2") AS ?postcode)

    OPTIONAL {
      ?rijksmonument ceo:heeftOorspronkelijkeFunctie/ceo:heeftFunctieNaam ?functies.
    }
  }

   graph owms: {
     ?prov skos:prefLabel ?provincie.
     ?gem skos:prefLabel ?gemeente.
   }

  OPTIONAL {
    graph graph:bebouwdeomgeving {
      ?functies skos:prefLabel ?functie_.
      BIND(replace(?functie_, "\\s\\(.*\\)|\\(.*\\)", "") AS ?functie)
    }
  }
}

❓ Question / Result #1.b
Summarize what is the result of this query and add in your report a description of this, together with a screenshot.

Now modify the query as follows:
- Add:
```
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
```
- Add (before the where part of the query):
```
?shape
```
- Within the graph graph:instanties-rce { ... } add:
```
OPTIONAL { ?rijksmonument ceo:heeftGeometrie/geo:asWKT ?shape. }
```
- Run the query, look at what is different in the Response, and see if the Geo view works (it should give you a map).
- What does not work yet is to be able to click on the points and see attributes for them. Now replace the label monumentenregister (without this the items in the map are clickable, but do not display ). Thus: ~~?monumentenregister~~ becomes: ?shapeLabel.
(Note, according to the documentation of yasgui: https://docs.triply.cc/yasgui/#geo-triplydb-plugin, you can also add ?xTooltip ?xLabel ?xColor which will be used for displaying the shape column labelled ?x).
- Change the query to limit the results to one Dutch province. Hint: if you want to filter the monuments only for those in Zuid-Holland, the label ?province in the graph owms: { ... } has to be replaced by the literal value: "Zuid-Holland"@nl (you can check the original query at the RCE to see what values you can use: https://linkeddata.cultureelerfgoed.nl/rce/-/queries/rijksmonumenten-gemeente-provincie/9 )

❓ Question / Result #1.c

Submit your modified query, include in your report: Your new query and screenshots of the result (Table and Map). Add an explanation of how the geometries are encoded in the returned result set.

B. Wikidata

Read the Wikidata introduction (first 3 sections, until ‘Text to SPARQL walkthrough’) here: https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/A_gentle_introduction_to_the_Wikidata_Query_Service
Try the following example query (“Airports within 100 km of Berlin”):

SELECT ?place ?placeLabel ?location
WHERE
{
  # Berlin coordinates
  wd:Q64 wdt:P625 ?berlinLoc .
  SERVICE wikibase:around {
    ?place wdt:P625 ?location .
    bd:serviceParam wikibase:center ?berlinLoc .
    bd:serviceParam wikibase:radius "100" .
  } .
  # Is an airport
  FILTER EXISTS { ?place wdt:P31/wdt:P279* wd:Q1248784 } .
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  }
}

Replace Berlin with Delft (or Athens or another city), and run the Airports query again
Hint: you have to find the <URI> for your chosen city first, use https://www.wikidata.org/wiki/Special:Search

❓ Question / Result #2

Include in your report:

Your adapted query

screenshot of result table and

screenshot of result map

❓ Question / Result #3
Once more, adapt the query to find hospitals within 30 km around that city (again, include 1. adapted query and screenshots of 2. result table and 3. result map in your report)

C. Federated query

Copy the following (federated) query into the Wikidata query window (https://query.wikidata.org/):

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX : <http://dbpedia.org/resource/>
PREFIX dbpedia2: <http://dbpedia.org/property/>
PREFIX dbpedia: <http://dbpedia.org/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX bd: <http://www.bigdata.com/rdf#>

SELECT *
WHERE 
{ 

SERVICE <http://dbpedia.org/sparql>
 {     
 ?person dbo:birthPlace  :Delft .      
 ?person foaf:name ?name .
FILTER (?name = "Johannes Vermeer"@en) .      
?person owl:sameAs ?samePerson .     
FILTER(STRSTARTS(STR(?samePerson), "http://www.wikidata.org")) 
 }

SERVICE <https://query.wikidata.org/sparql>
 {
 ?samePerson wdt:P551 ?residence .
 ?residence wdt:P625 ?coordinates .
 }

}
LIMIT 10

Examine the contents of the query.
Then, run the query.

❓ Question / Result #4

Explain/add in your report:

What does, in plain English, the query ask for?

What is the role of SERVICE in this query?

How is the link between the DBPedia triples and Wikidata triples achieved?

In the result table: Which information comes from DBPedia, which information comes from Wikidata?

Adapt the query. Change ‘Delft’ to another city name and run again. Include the adapted query plus screenshot of the result table in your report.

D. Write a comparison between DBPedia and Wikidata

Do some research and discover what the main differences and similarities between DBPedia and Wikidata are.

❓ Question / Result #5

Write a short explanation about it in your own words (200 words max) and include it in your report.

What to submit

Submit via Brightspace:
- Your report with answers (descriptions/explanations, adapted queries, and screenshots of the query results)